【サンプル付き】大量のcsvファイル結合

Sub FileCombine()

Dim bkPath_Log As String
Dim check_CombineFile As String
Dim folder_Path As String
Dim csvFile As String
Dim buf As String

'対象フォルダを指定
MsgBox " csvファイルを結合するよ! csvファイルが入ったフォルダを選択してね(^o^)"

With Application.FileDialog(msoFileDialogFolderPicker)
    If .Show = True Then
        folder_Path = .SelectedItems(1)
    Else
        MsgBox "フォルダが正しく選択されなかったので終了します（#^ω^）"
        Exit Sub
    End If
End With

'事前にcombine.csvが存在するか確認
check_CombineFile = Dir(folder_Path & "\*.csv")

Do While check_CombineFile <> ""
    If check_CombineFile = "combine.csv" Then   
        MsgBox "既に「combine.csv」ファイルが存在するため終了します"
        Exit Sub   
    End If   
    check_CombineFile = Dir()
Loop

'csvファイルが存在しない場合終了
bkPath_Log = Dir(folder_Path & "\*.csv")
If bkPath_Log = "" Then    
    MsgBox "ファイルが存在しません(ﾉД`)ｼｸｼｸ"
    Exit Sub
End If
csvFile = folder_Path & "\combine.csv"

'新規csvファイルを作成
Open csvFile For Append As #1

    'ファイルが存在する限り
    Do While Len(bkPath_Log) > 0
        'ファイルをOpenして追記
        If bkPath_Log <> "combine.csv" Then     
            Open folder_Path & "\" & bkPath_Log For Input As #2             
                Do Until EOF(2)               
                    Line Input #2, buf
                    Print #1, buf      
                Loop
            Close #2       
        End If       
        'Dir関数で次のファイルへ
        bkPath_Log = Dir()
    Loop
Close #1
MsgBox "combine.csvにcsvファイルを結合しました(｀･ω･´)ゞ"

End Sub